ESP8266 Community Forum

Posted: **Fri Apr 05, 2019 2:04 pm**

DHT_Tester.ino

When I attempt to test a DHT22 using a nodeMCU I get the following error message:

FindFirstFile C:\Users\xxxxx\AppData\Local\Temp\arduino_cache_945155:
The system cannot find the file specified.

Error compiling for board NodeMCU 1.0 (ESP-12E Module).
The file is attached.
Any help would be appreciated.

Posted: **Fri Apr 05, 2019 2:34 pm**

Not that I do not trust you but I do not intend on downloading a file from someone I do not know. If nothing else I would have to save the file to my PC to read it and that would mean adding a new folder then deleting it all when I had finished. Anyway I would just post the code here.

Have you got anything to work yet?

Posted: **Fri Apr 05, 2019 3:05 pm**

Try putting the sensor on a different pin. Pin 2 often has an LED (with series resistor) connected to it with a . That might be too hard for the sensor to pull low.

Try connecting to GPIO 4,5,12,13, or 14. Use a pull up resistor of about 4K7.

That is a small file and it would be better if you were to just post in in the body of your post.

Code: Select all

// Example testing sketch for various DHT humidity/temperature sensors
// Written by ladyada, public domain

// REQUIRES the following Arduino libraries:
// - DHT Sensor Library: https://github.com/adafruit/DHT-sensor-library
// - Adafruit Unified Sensor Lib: https://github.com/adafruit/Adafruit_Sensor

#include "DHT.h"

#define DHTPIN 2     // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.

// Uncomment whatever type you're using!
//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

// Connect pin 1 (on the left) of the sensor to +5V
// NOTE: If using a board with 3.3V logic like an Arduino Due connect pin 1
// to 3.3V instead of 5V!
// Connect pin 2 of the sensor to whatever your DHTPIN is
// Connect pin 4 (on the right) of the sensor to GROUND
// Connect a 10K resistor from pin 2 (data) to pin 1 (power) of the sensor

// Initialize DHT sensor.
// Note that older versions of this library took an optional third parameter to
// tweak the timings for faster processors.  This parameter is no longer needed
// as the current DHT reading algorithm adjusts itself to work on faster procs.
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  Serial.println(F("DHTxx test!"));

  dht.begin();
}

void loop() {
  // Wait a few seconds between measurements.
  delay(2000);

  // Reading temperature or humidity takes about 250 milliseconds!
  // Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
  float h = dht.readHumidity();
  // Read temperature as Celsius (the default)
  float t = dht.readTemperature();
  // Read temperature as Fahrenheit (isFahrenheit = true)
  float f = dht.readTemperature(true);

  // Check if any reads failed and exit early (to try again).
  if (isnan(h) || isnan(t) || isnan(f)) {
    Serial.println(F("Failed to read from DHT sensor!"));
    return;
  }

  // Compute heat index in Fahrenheit (the default)
  float hif = dht.computeHeatIndex(f, h);
  // Compute heat index in Celsius (isFahreheit = false)
  float hic = dht.computeHeatIndex(t, h, false);

  Serial.print(F("Humidity: "));
  Serial.print(h);
  Serial.print(F("%  Temperature: "));
  Serial.print(t);
  Serial.print(F("Â°C "));
  Serial.print(f);
  Serial.print(F("Â°F  Heat index: "));
  Serial.print(hic);
  Serial.print(F("Â°C "));
  Serial.print(hif);
  Serial.println(F("Â°F"));
}

Posted: **Sat Apr 06, 2019 2:32 pm**

Switching to GPIO pin 4 did the trick. Many thanks!!

ESP8266 Community Forum

Trying to test a DHT22 without success

Trying to test a DHT22 without success

Re: Trying to test a DHT22 without success

Re: Trying to test a DHT22 without success

Re: Trying to test a DHT22 without success